Exploring Where & Why/Exploring Where & Why.iso/pc/Lib.cst/00033_MemberAnimation.ls

Text File | 2004-07-11 | 5.5 KB | 206 lines

--
-- MemberAnimation
--
-- manage animations based on a member rather than a sprite.

-- final animation list will be as follows:
-- [[#memberName.castLibName:[1:[#mNum:num, #cNum:num, #loc:point],2:[...], ...],member.castLib:[...]]



property ancestor

-- constants:
property animationListMember  -- the field containing the list.
property animationSprite  -- the sprites containing the animation information
property animationRate

-- the list of member animations:
property memberAnimations


on new me
  -- set the constants:
  set animationListMember = "animationLists"
  set animationSprite = 1
  set animationRate = .25

  set ancestor = new (script "GraphTool")

  set memberAnimations = [:]

  return me
end


on destruct me
  if objectP (ancestor) then destruct (ancestor)
  set ancestor = 0
end


-- animate a list of sprites simultaneously
-- relative to their current screen location.

on animateSprites me, spriteLst
  -- puppet all of us to true
  -- and get original sprite member information:
  set startInfoLst = [:]
  set workingSpriteLst = [:]
  repeat with spr in spriteLst
    if weHaveAnimation (me, spr) then
      puppetSprite spr, TRUE
      addProp (startInfoLst, spr, getAnimSpriteInfo (me, spr))
      addProp (workingSpriteLst, spr, getAnimName (me, spr))
    end if
  end repeat

  -- run the animations:
  if count (workingSpriteLst) then
    set tot = getLongestAnim (me, workingSpriteLst)
    repeat with i = 1 to tot
      setAnimFrame (me, workingSpriteLst, startInfoLst, i)
      updateStage
      wait (me, animationRate)
    end repeat
  end if

  -- return sprites to their original states:
  set tot = count (startInfoLst)
  repeat with i = 1 to tot
    set spr = getPropAt (startInfoLst, i)
    set rec = getProp (startInfoLst, spr)
    setAnimSpriteInfo (me, spr, rec)
  end repeat
  updateStage
end



-- add animations to the master list of member animations:
-- list passed is formatted as follows: [#memberName:memberNum, #memberName:memberNum, ... ]
-- cNum is the castLibNum for the list of animations.

on addAnimations me, cNum, lst
  -- get the starting frame so that you can return to it later:
  set startFrame = the frame

  if not listP (memberAnimations) then set memberAnimations = [:]

  set cName = the name of castLib cNum -- the name of the current cast library
  repeat with m = 1 to count (lst)
    set mName = string(getPropAt (lst, m))
    set mNum = getAProp (lst, m)

    set prop = string (mName & "." & cName)
    -- if a layout for this animation exists, then create a rec and store it.
    if label (prop) then
      set animRec = getMemberAnimation (me, prop)
      addProp (memberAnimations, value ("#" & prop), animRec)
    end if
  end repeat

  -- store it:
  makeField (me, animationListMember, memberAnimations)

  -- return to your starting frame:
  go frame startFrame
end


-- get a member animation record from a series of frames.
-- return a prop list as follows:
-- [1:[#mNum:num, #cNum:num, #loc:point], 2:[#mNum:num, #cNum:num, #loc:point], ... ]

on getMemberAnimation me, stFrame
  set rec = [:]
  -- go to that animation layout sequence in the score:
  go stFrame
  set i = 1

  repeat while the type of sprite 1 <> 0
    -- gather information for that animation frame:
    addProp (rec, i, getAnimSpriteInfo (me, animationSprite))
    set i = i + 1
    go the frame + 1
  end repeat

  return rec
end


-- return the largest number of frames in an animation:

on getLongestAnim me, spriteLst
  set num = 0
  set tot = count (spriteLst)
  repeat with i = 1 to tot
    set spr = getPropAt (spriteLst, i)
    set prop = getAnimName (me, spr)
    set tmpLst = getaProp (memberAnimations, prop)
    if not voidP (tmpLst) then
      set c = count (tmpLst)
      if c > num then set num = c
    end if
  end repeat
  return num
end


-- check to see if we have an animation in the master record:

on weHaveAnimation me, spr
  set name = getAnimName (me, spr)
  if voidP (getAProp (memberAnimations, name)) then return 0
  else return 1
end




on getAnimName me, spr
  return string(the name of member the memberNum of sprite spr of castLib the castLibNum of sprite spr & "." & the name of castLib the castLibNum of sprite spr)
end



-- make changes to sprites in spriteLst for the current frame:

on setAnimFrame me, spriteLst, startInfoLst, frameNum
  set tot = count (spriteLst)
  repeat with i = 1 to tot
    -- get next sprite number:
    set spr = getPropAt (spriteLst, i)
    -- get next memberAnimation name
    set name = getProp (spriteLst, spr)
    -- get the current frame member record:
    set workingAnim = getaProp (memberAnimations, name)
    -- get the sprite's starting information rec:
    set startInfoRec = getaProp (startInfoLst, spr)
    set offSetLoc = getaProp (startInfoRec, #loc)
    if not voidP (workingAnim) then
      setAnimSpriteInfo (me, spr, getaProp (workingAnim, frameNum), offSetLoc)
    end if
  end repeat
end


-- get information from an animation sprite in the current frame:

on getAnimSpriteInfo me, spr
  return [#mNum:(the memberNum of sprite spr), #cNum:(the castLibNum of sprite spr), #loc:(the loc of sprite spr)]
end


-- set information from an animation sprite record:

on setAnimSpriteInfo me, spr, rec, locOffSet
  if voidP (rec) then return
  if voidP (locOffSet) then set locOffSet = point (0,0)
  else set locOffSet = (locOffSet - point (320,240))
  puppetSprite spr, TRUE
  set the memberNum of sprite spr = getProp (rec, #mNum)
  set the castLibNum of sprite spr = getProp (rec, #cNum)
  set the loc of sprite spr = getProp (rec, #loc) + locOffSet
end